질문글

http://gigglehd.com/zbxe/14246644

위 질문글에서 이어지는 결론입니다만

결국 AutoHotkey라는 프로그램을 이용해서 결론을 봤습니다.

노트북의 우측 숫자패드 1(NumpadEnd) 2(NumpadDown) 3(NumpadPgDn)을 이용해서

1번은 한글입력 2번은 일본어전각입력 3번은 영문입력으로 전환되게 수정하였습니다.

지정하고 쓰다보니 상당히 편하네요

기글에는 다국어로 글을 작성하시는 분이 많을 것 같아 자유게시판에 스크립트를 공계합니다. 원스크립트 출처도 아래 있습니다.

혹시 제가 작성한 방법에서 더욱 좋게 개선하는 방법이 있다면 조언 부탁드립니다.

NumpadPgDn에서 바로 영어입력 shortcut키로 지정하지 않은 이유는 윈도우10의 버그로 영문입력의 숏컷은 재부팅시 설정이 지워지는 버그가 있어서 입니다.(한글,일본어 입력 숏컷은 멀쩡함)

IME_CHECK(WinTitle)

{

    WinGet,hWnd,ID,%WinTitle%

    Return Send_ImeControl(ImmGetDefaultIMEWnd(hWnd),0x005,"")

}

Send_ImeControl(DefaultIMEWnd, wParam, lParam)

{

    DetectSave := A_DetectHiddenWindows       

    DetectHiddenWindows,ON                          

     SendMessage 0x283, wParam,lParam,,ahk_id %DefaultIMEWnd%

    if (DetectSave <> A_DetectHiddenWindows)

        DetectHiddenWindows,%DetectSave%

    return ErrorLevel

}

ImmGetDefaultIMEWnd(hWnd)

{

    return DllCall("imm32\ImmGetDefaultIMEWnd", Uint,hWnd, Uint)

}

NumpadEnd::                    ; I want NumpadEnd key to be "Absolutely Hangul" mode key. I hate toggling :(

   send, +^1                   ; You need to make shortcut first, on windows control panel, +^1 is Hangul mode.

    ret := IME_CHECK("A")

    if %ret% = 0                ; 0 means IME is in English mode now.

    {

        Send, {vk15sc138}       ; Turn IME into Hangul(Korean) mode.

    }

return

NumpadDown::                   ; I want NumpadDown key to be "Absolutely Japanese" mode key. I hate toggling :(

   send, +^3                   ; You need to make shortcut first, on windows control panel, +^3 is Japanese mode.

    ret := IME_CHECK("A")

    if %ret% = 0                ; 0 means IME is in English mode now.

    {

        Send, {sc029}       ; Turn IME into Japanese(Zenkaku) mode.

    }

return

NumpadPgDn::

   send, +^1                   ; You need to make shortcut first, on windows control panel, +^1 is Hangul mode.

   Sleep,0050

   send, #{space}              ; and change to English mode.

return

원 스크립트 출처

http://www.autohotkey.co.kr/cgi/board.php?bo_table=script&wr_id=357&sfl=&stx=&sst=wr_hit&sod=desc&sop=and&page=4